Reading Audio Device

[larrybtoys]

Is there a way in GB32 to see if there is an audio device attached to the PC. I had a situation where someone was playing one of my games on a PC with no audio device attached and the program crashed. When running the program again and turning off sounds in the game it ran fine. TIA

[Xavier]

This returns a listing of devices using: Winmm.dll

Declare Function waveOutGetNumDevs Lib "winmm.dll" () As Integer
Declare Function waveOutGetDevCaps Lib "winmm.dll" Alias "waveOutGetDevCapsA" ( _
ByVal uDeviceID As Integer, lpCaps As WAVEOUTCAPS, ByVal uSize As Integer) As Integer

Const MAXPNAMELEN = 32
Type WAVEOUTCAPS
 wMid          As Int16
 wPid          As Int16
 vDriverVersion As Long
 szPname       As String * MAXPNAMELEN
 dwFormats     As Long
 wChannels     As Int16
 wReserved1    As Int16
 dwSupport     As Long
EndType
Dim numDevices As Long
Dim caps As WAVEOUTCAPS
Dim i As Long

' Get the number of devices
numDevices = waveOutGetNumDevs()

' Iterate over each device
Dim i%
For i = 0 To numDevices - 1
 ' Get the capabilities of the device
 waveOutGetDevCaps(i, caps, Len(caps))
 
 ' Print the name of the device
 Debug.Print (caps.szPname)
Next i


Debug output:

Headset Earphone (Jabra UC VOIC
Speakers (High Definition Audio
Digital Audio (S/PDIF) (High De
Digital Audio (S/PDIF) (High De

[dragonjim]

If that doesn't help - although I don't see why it shouldn't - you could insert test code in a Try/Catch structure at the start of the code which tries to play audio and catches an error if any occurs.

[Xavier]

Here is a walk-thru video that I cranked out ... 

Let me know if this type of video is useful to you.

Demo Get Audio Device Count.G32 (1.01 KB)

[Xavier]

Were you able to use this info?

[larrybtoys]

Not yet. I need some time to dig into the code as the only thing I need is a 1 or 0 as to whether or not there are any audio devices present. I don't want a list of them. I have been busy getting the game jam game finished and submitted to the contest plus working on 2 other games and imaging 12 desktops and 1 laptop for installation...

[larrybtoys]

It appears that all I need to do it insert the following code in my program:

Declare Function waveOutGetNumDevs Lib "winmm.dll" () As Integer
Declare Function waveOutGetDevCaps Lib "winmm.dll" Alias "waveOutGetDevCapsA" ( _
ByVal uDeviceID As Integer, lpCaps As WAVEOUTCAPS, ByVal uSize As Integer) As Integer

Const MAXPNAMELEN = 32
Type WAVEOUTCAPS
wMid As Int16
wPid As Int16
vDriverVersion As Long
szPname As String * MAXPNAMELEN
dwFormats As Long
wChannels As Int16
wReserved1 As Int16
dwSupport As Long
EndType
Dim numDevices As Long
Dim caps As WAVEOUTCAPS
Dim i As Long

When I need to find out if there is an audio device resent I simply put this line of code in:
numDevices = waveOutGetNumDevs()

And then:
If numDevices > 0
'OK to activate sounds
Else
'Not OK to activate sounds
Endif

[Xavier]

You should be able to get away with:

Declare Function waveOutGetNumDevs Lib "winmm.dll" () As Integer

// If the returned value of waveOutGetNumDevs is not 0 then AudioOutExists? should be True

Dim AudioOutExists? = CBool(waveOutGetNumDevs)